mirror of
https://github.com/dragonpilot/dragonpilot.git
synced 2026-02-19 21:44:01 +08:00
fb496c692a
* Squashed vipc * Update release files * Remove else * add visionipc to release files * use poller in vipc receive * opencl framework instead of lib on macos * Fix camera webcam * Fix opencl on mac in ui * more webcam fixes * typo in ui sconsfile * Use cur_yuv_buf * visionbuf c++ class * Camera qcom was still using visionbuf_allocate * Turn loggerd back on * fix snapshot * No build needed * update test camerad * no more release callback * make encoder c++ * Revert "no more release callback" This reverts commit e5707b07002fee665d0483d90713154efc2d70d4. * fix exit handlers * No need to check errno * move release callback call * s/VIPCBufExtra/VisionIpcBufExtra/g * use non blocking connect * ui use non blocking connect * Lower condition variable wait time * Snapshot cleanup * bump cereal * bump cereal
53 lines
2.1 KiB
Python
53 lines
2.1 KiB
Python
import os
|
|
Import('env', 'qt_env', 'arch', 'common', 'messaging', 'gpucommon', 'visionipc', 'cereal')
|
|
|
|
|
|
src = ['ui.cc', 'paint.cc', 'sidebar.cc', '#phonelibs/nanovg/nanovg.c']
|
|
libs = [common, 'zmq', 'capnp', 'kj', 'm', 'OpenCL', cereal, messaging, gpucommon, visionipc]
|
|
|
|
|
|
if qt_env is None:
|
|
libs += ['EGL', 'GLESv3', 'gnustl_shared', 'log', 'utils', 'gui', 'hardware',
|
|
'ui', 'CB', 'gsl', 'adreno_utils', 'OpenSLES', 'cutils', 'uuid', 'OpenCL']
|
|
linkflags = ['-Wl,-rpath=/system/lib64,-rpath=/system/comma/usr/lib']
|
|
|
|
src += ["android/ui.cc", "android/sl_sound.cc"]
|
|
env.Program('_ui', src,
|
|
LINKFLAGS=linkflags,
|
|
LIBS=libs)
|
|
else:
|
|
qt_libs = qt_env["LIBS"] + libs + ["pthread", "ssl", "crypto"]
|
|
|
|
widgets = qt_env.Library("qt_widgets",
|
|
["qt/qt_window.cc", "qt/qt_sound.cc", "qt/widgets/keyboard.cc", "qt/widgets/input_field.cc", "qt/widgets/drive_stats.cc",
|
|
"qt/offroad/wifi.cc", "qt/offroad/wifiManager.cc", "qt/widgets/toggle.cc", "qt/widgets/offroad_alerts.cc"],
|
|
LIBS=qt_libs)
|
|
qt_libs.append(widgets)
|
|
|
|
if arch == "Darwin":
|
|
# fix OpenCL
|
|
del qt_libs[qt_libs.index('OpenCL')]
|
|
qt_env['FRAMEWORKS'] += ['OpenCL']
|
|
|
|
qt_src = ["qt/ui.cc", "qt/window.cc", "qt/home.cc", "qt/offroad/settings.cc", "qt/offroad/onboarding.cc"] + src
|
|
qt_env.Program("_ui", qt_src, LIBS=qt_libs)
|
|
|
|
# spinner and text window
|
|
qt_env.Program("qt/text", ["qt/text.cc"], LIBS=qt_libs)
|
|
qt_env.Program("qt/spinner", ["qt/spinner.cc"], LIBS=qt_libs)
|
|
|
|
# build setup, factory resetter, and installer
|
|
if "BUILD_SETUP" in os.environ:
|
|
qt_env.Program("qt/setup/reset", ["qt/setup/reset.cc"], LIBS=qt_libs)
|
|
qt_env.Program("qt/setup/setup", ["qt/setup/setup.cc"], LIBS=qt_libs + ['curl', 'common'])
|
|
|
|
installers = [
|
|
("openpilot", "master"),
|
|
("openpilot_test", "master"),
|
|
#("dashcam", "dashcam"),
|
|
#("dashcam_test", "dashcam"),
|
|
]
|
|
for name, branch in installers:
|
|
flags = qt_env["CXXFLAGS"] + [f"-D{branch}"]
|
|
qt_env.Program(f"qt/setup/installer_{name}", ["qt/setup/installer.cc"], LIBS=qt_libs)
|