mirror of
https://github.com/dragonpilot/dragonpilot.git
synced 2026-02-19 02:54:01 +08:00
302d06ee70
* thneed runs the model * thneed is doing the hooking * set kernel args * thneeding the bufferS * print the images well * thneeds with better buffers * includes * disasm adreno * parse packets * disasm works * disasm better * more thneeding * much thneeding * much more thneeding * thneed works i think * thneed is patient * thneed works * 7.7% * gpuobj sync * yay, it mallocs now * cleaning it up, Thneed * sync objs and set power * thneed needs inputs and outputs * thneed in modeld * special modeld runs * can't thneed the DSP * test is weird * thneed modeld uses 6.4% CPU * add thneed to release * move to debug * delete some junk from the pr * always track the timestamp * timestamp hacks in thneed * create a new command queue * fix timestamp * pretty much back to what we had, you can't use SNPE with thneed * improve thneed test * disable save log Co-authored-by: Comma Device <device@comma.ai>
48 lines
1.2 KiB
Python
48 lines
1.2 KiB
Python
Import('env', 'arch', 'messaging', 'common', 'gpucommon', 'visionipc')
|
|
lenv = env.Clone()
|
|
|
|
libs = [messaging, common, 'OpenCL', 'SNPE', 'capnp', 'zmq', 'kj', 'yuv', gpucommon, visionipc]
|
|
|
|
TEST_THNEED = False
|
|
|
|
common_src = [
|
|
"models/commonmodel.c",
|
|
"runners/snpemodel.cc",
|
|
"transforms/loadyuv.c",
|
|
"transforms/transform.c"]
|
|
|
|
if arch == "aarch64":
|
|
libs += ['gsl', 'CB', 'gnustl_shared']
|
|
if not TEST_THNEED:
|
|
common_src += ["thneed/thneed.cc"]
|
|
lenv['CFLAGS'].append("-DUSE_THNEED")
|
|
lenv['CXXFLAGS'].append("-DUSE_THNEED")
|
|
elif arch == "larch64":
|
|
libs += ['gsl', 'CB', 'symphony-cpu', 'pthread']
|
|
else:
|
|
libs += ['symphony-cpu', 'pthread']
|
|
|
|
# for tensorflow support
|
|
common_src += ['runners/tfmodel.cc']
|
|
# tell runners to use it
|
|
lenv['CFLAGS'].append("-DUSE_TF_MODEL")
|
|
lenv['CXXFLAGS'].append("-DUSE_TF_MODEL")
|
|
|
|
common = lenv.Object(common_src)
|
|
|
|
lenv.Program('_dmonitoringmodeld', [
|
|
"dmonitoringmodeld.cc",
|
|
"models/dmonitoring.cc",
|
|
]+common, LIBS=libs)
|
|
|
|
lenv.Program('_modeld', [
|
|
"modeld.cc",
|
|
"models/driving.cc",
|
|
]+common, LIBS=libs)
|
|
|
|
if TEST_THNEED:
|
|
lenv.Program('thneed/debug/_thneed', [
|
|
"thneed/thneed.cc", "thneed/debug/test.cc"
|
|
]+common, LIBS=libs)
|
|
|